Iran Save2.tri file -DRAFT

Iran theater

Moderators: Lone Wolf, Snake Man

Post Reply
User avatar
Sherlock
Lt. General
Posts: 1167
Joined: 2006-05-24 22:01:01
Gaming Interests: Falcon 4.0
Editing Interests: All, I (try) to edit everything.
Location: Arizona, USA

Iran Save2.tri file -DRAFT

Post by Sherlock » 2010-08-09 16:39:49

This is for AF only but could be edited for other versions of Falcon pretty easily I would think. I noticed the red side was unplayable in V0.3.1 so I did this TRI file to fix that. The red side clock now advances normally with this TRI file installed for the SAVE2.CAM file:

Code: Select all

//
// Base event file
//
// Iran Save2: Operation Hammerfall
//
// :::::::::::::::::::::::::::::::::::::::::;
//
//
#TOTAL_EVENTS 22
//
// :::::::::::::::::::::::::::::::::::::::::;
// 
// This marks the Coalition as initially on the offensive
#SET_EVENT 9
#RESET_EVENT 10
// This marks the Iranians as having advanced beyond the border
#SET_EVENT 6
#SET_EVENT 7
#PARENTRECALCDEPTH 4
#FLOT_SORTDISTANCE 20
#FLOT_DRAWDISTANCE 50
#MINEVALUATEAIRBASEDISTANCE 20
#SET_TEMPO 255
#ENDINIT
//
// :::::::::::::::::::::::::::::::::::::::::;
// 
// Event #1
// Baghdad being attacked by Iranian forces
// 
#IF_EVENT_PLAYED 1
#ELSE
  #IF_CONTR_ALLIES 6 O 4716 4712 4681 4724 4674
    #PLAY_MOVIE 100
    #SET_PAK_PRIORITY 6 4701 100
    #SET_PAK_PRIORITY 2 4701 100
    #CHANGE_PRIORITIES 6 2
    #CHANGE_PRIORITIES 2 1
    #DO_EVENT 1
  #ENDIF
#ENDIF
//
// Event #2
// Baghdad falls/regained
// 
#IF_EVENT_PLAYED 2
  #IF_CONTR_ALLIES 2 A 4703 4695 9041 4490 4712 4702 4701 4488
    #SHIFT_INITIATIVE 2 6 50
    #RESET_EVENT 2
  #ENDIF
#ELSE
  #IF_CONTR_ALLIES 6 A 4703 4695 9041 4490 4712 4702 4701 4488
    #PLAY_MOVIE 101
    #DO_EVENT 2
    #SHIFT_INITIATIVE 6 2 50
  #ENDIF
#ENDIF
// 
// Event#3
// Tehran being attacked by Coalition forces
// 
#IF_EVENT_PLAYED 3
#ELSE
  #IF_CONTR_ALLIES 2 O 1453 1268 1182 1125 1520 1491 999 1070
    #SET_PAK_PRIORITY 6 1180 100
    #SET_PAK_PRIORITY 2 1180 100
    #CHANGE_PRIORITIES 6 1
    #CHANGE_PRIORITIES 2 2
    #SET_TEMPO 255
    #PLAY_MOVIE 102
    #DO_EVENT 3
  #ENDIF
#ENDIF
// 
// Event#4
// Tehran falls/regained
// 
#IF_EVENT_PLAYED 4
  #IF_CONTR_ALLIES 6 A 1211 1180 14435
    #SHIFT_INITIATIVE 2 6 50
    #RESET_EVENT 4
  #ENDIF
#ELSE
  #IF_CONTR_ALLIES 2 A 1211 1180 14435
    #PLAY_MOVIE 103
    #DO_EVENT 4
    #SHIFT_INITIATIVE 6 2 50
  #ENDIF
#ENDIF
//
// Event#5
// Iranians advance beyond the Iran-Iraq border
//
#IF_EVENT_PLAYED 5
#ELSE
  #IF_EVENT_PLAYED 7
  #ELSE
    #IF_CONTR_ALLIES 6 O 4533 4545 4582 1540 4640 4677 4726 4766 4814 4925
      #DO_EVENT 5
      #RESET_EVENT 6
    #ENDIF
  #ENDIF
#ENDIF
// 
// Event#6
// Iranians pushed back to the border
// 
#IF_EVENT_PLAYED 5
  #IF_EVENT_PLAYED 7
    #PLAY_MOVIE 104
    #DO_EVENT 6
    #RESET_EVENT 5
  #ELSE
    #IF_CONTR_ALLIES 2 A 4924 4855 4818 4766 1826 4676 4640 4582 4533 
      #PLAY_MOVIE 104
      #DO_EVENT 6
      #RESET_EVENT 5
    #ENDIF
  #ENDIF
#ENDIF
// 
// Event#7
// Coalition forces advance beyond the Iran-Iraq border
//
#IF_EVENT_PLAYED 7
#ELSE
  #IF_EVENT_PLAYED 5
  #ELSE
    #IF_CONTR_ALLIES 2 O 997 1092 1278 1334 1445 1548 1666 1721 1868 1939 2190 2475
      #DO_EVENT 7
      #RESET_EVENT 8
    #ENDIF
  #ENDIF
#ENDIF
// 
// Event#8
// Coalition forces pushed back to the Iran-Iraq border
// 
#IF_EVENT_PLAYED 7
  #IF_EVENT_PLAYED 5
    #PLAY_MOVIE 105
    #DO_EVENT 8
    #RESET_EVENT 7
  #ELSE
    #IF_CONTR_ALLIES 6 A 4924 4908 4818 4766 4717 4676 4640 4582 4533
      #PLAY_MOVIE 105
      #DO_EVENT 8
      #RESET_EVENT 7
    #ENDIF
  #ENDIF
#ENDIF
// 
// Event#9
// Coalition forces go on offensive
// 
#IF_EVENT_PLAYED 10
  #IF_ON_OFFENSIVE 2
    #PLAY_MOVIE 106
    #DO_EVENT 9
    #RESET_EVENT 10
  #ENDIF
#ENDIF
// 
// Event#10
// Coalition forces go on the defensive
// 
#IF_EVENT_PLAYED 9
  #IF_ON_OFFENSIVE 6
    #PLAY_MOVIE 107
    #DO_EVENT 10
    #RESET_EVENT 9
  #ENDIF
#ENDIF
// 
// Event#11
// Pakistan Joins the war
//
#IF_EVENT_PLAYED 11
#ELSE
  #IF_CAMPAIGN_DAY G 3
    #IF_FORCE_RATIO A 6 2 L 3
      #IF_RANDOM_CHANCE 5
        #IF_CONTR_ALLIES 2 O 2277 2492 1584 1138 177
          #CHANGE_RELATIONS 5 6 1
          #PLAY_MOVIE 108
          #SHIFT_INITIATIVE 2 6 50
          #DO_EVENT 11
        #ENDIF
      #ENDIF
      #IF_EVENT_PLAYED 3
        #IF_RANDOM_CHANCE 40
          #CHANGE_RELATIONS 5 6 1
          #PLAY_MOVIE 108
          #SHIFT_INITIATIVE 2 6 50
          #DO_EVENT 11
        #ENDIF
      #ENDIF
    #ENDIF
  #ENDIF
#ENDIF
// 
// Event#12
// CIS joins the war
//
#IF_EVENT_PLAYED 12
#ELSE
  #IF_CAMPAIGN_DAY G 4
    #IF_FORCE_RATIO A 6 2 L 2
      #IF_RANDOM_CHANCE 2
        #IF_CONTR_ALLIES 2 O 1898 1635 
          #CHANGE_RELATIONS 4 6 1
          #PLAY_MOVIE 109
          #SHIFT_INITIATIVE 2 6 50
          #DO_EVENT 12
        #ENDIF
      #ENDIF
    #ENDIF
  #ENDIF
#ENDIF
// 
// Event#14
// Bad guys win; Basically did Baghdad and Al Kuwayt fall
// 
#IF_CONTR_ALLIES 6 A 4701 4957
  #PLAY_MOVIE 113
  #DO_EVENT 14
  #END_GAME 14
#ENDIF
// 
// Event#15
// Stalemate; put player out of his misery
// 
#IF_BORDOM_HOURS 120
  #PLAY_MOVIE 114
  #DO_EVENT 15
  #END_GAME 15
#ENDIF
// 
// Event#16
// Timeout
// 
#IF_CAMPAIGN_DAY G 14
  #PLAY_MOVIE 115
  #DO_EVENT 16
  #END_GAME 16
#ENDIF
// 
// Event#17
// Good guys win - Hu-rah!!; Basically-we own Tehran, Bandar Abbas and Kerman
// 
#IF_CONTR_ALLIES 2 A 3347 1180 2632
  #PLAY_MOVIE 116
  #DO_EVENT 17
  #END_GAME 17
#ENDIF
#ENDSCRIPT
Sherlock
Victurous te Saluto

demer928
Banned user
Posts: 208
Joined: 2009-05-06 20:48:30
Gaming Interests: Falcon 4.0
Editing Interests: All, I (try) to edit everything.

Re: Iran Save2.tri file -DRAFT

Post by demer928 » 2010-08-09 20:20:34

Thank's man,

Not on save2 ATM as you know, but will keep this as draft when I get done with the FF base file. :wink:


demer

Post Reply

Who is online

Users browsing this forum: No registered users and 11 guests