Theatre Trigger question

[Ender Wiggin]

Is it possible to have a country join a particular side based on a trigger, like Russia being ally or axis based on a triggered event?

[ccc]

i dont think you can simulate politics in falcon world, it simply too complex for f4 engine :p

honestly, it seems Russian or china is *designed to join DPRK* after some cities being captured by US/ROK. a matter of timing.

[BenBen]

I haven't understood completely how it works yet but I know that this is controlled by the .tri files in the campaign folder. If you have a look at the comments in the file then you can see that the team relations get changed when certain conditions are met.

[Bird-FF]

This is possible using the TRI scripts.

This is example on how to do. I figured it out durn my attempt to revamp the israeli theater. Unforunately I lost my HD, and I cannot find the many backups I make of my work. You can check this post for more on the defunct attempt: http://www.freefalcon.com/forum/viewtopic.php?t=7801
The post is located in a developers sect, so you may not beable to look.

Now to the TRI script. I'll post it here, and hopefully you can see what your looking for:

// FF3 Israeli Theater Update
// Campaign 1: ARAB ALLIANCE - 2004
// Campaign Designed by Bird : www.freefalcon.com - www.falcon4world.com

#TOTAL_EVENTS 22
#SET_EVENT 2
#SET_TEMPO 255
#ENDINIT

//Saudi and Iraq are removed from this conflict / Set up PAK priorities
#IF_EVENT_PLAYED 9
#ELSE
#CHANGE_RELATIONS 7 0 1
#CHANGE_RELATIONS 3 0 1
#SET_PAK_PRIORITY 2 1487 50
#SET_PAK_PRIORITY 2 580 50
#SET_PAK_PRIORITY 2 313 90
#SET_PAK_PRIORITY 2 9 90
#SET_PAK_PRIORITY 2 650 80
#SET_PAK_PRIORITY 2 1100 60
#SET_PAK_PRIORITY 2 1237 60
#SET_PAK_PRIORITY 2 760 10
#SET_PAK_PRIORITY 2 1400 0
#SET_PAK_PRIORITY 2 1356 0
#SET_PAK_PRIORITY 6 313 100
#SET_PAK_PRIORITY 6 173 80
#SET_PAK_PRIORITY 6 183 80
#SET_PAK_PRIORITY 6 1487 50
#SET_PAK_PRIORITY 6 580 50
#SET_PAK_PRIORITY 6 9 100
#SET_PAK_PRIORITY 6 650 50
#SET_PAK_PRIORITY 6 1100 50
#SET_PAK_PRIORITY 6 1237 50
#SET_PAK_PRIORITY 6 760 30
#SET_PAK_PRIORITY 6 1400 0
#SET_PAK_PRIORITY 6 1356 0
#DO_EVENT 9
#ENDIF
#ENDIF

//Syria joins Eygpt to start Arab war effort
#IF_EVENT_PLAYED 1
#ELSE
#CHANGE_RELATIONS 5 6 1
#SHIFT_INITIATIVE 6 2 20
#PLAY_MOVIE 112
#DO_EVENT 1
#ENDIF
#ENDIF

//Israeli's on Offensive
#IF_EVENT_PLAYED 2
#IF_ON_OFFENSIVE 2
#SHIFT_INITIATIVE 6 2 50
#PLAY_MOVIE 106
#DO_EVENT 3
#RESET_EVENT 2
#ENDIF
#ENDIF

//Israeli's on Defensive
#IF_EVENT_PLAYED 3
#IF_ON_OFFENSIVE 6
#SHIFT_INITIATIVE 2 6 50
#PLAY_MOVIE 107
#DO_EVENT 2
#RESET_EVENT 3
#ENDIF
#ENDIF

//Jordan joins the Arab war effort / Set up PAK priorities
#IF_EVENT_PLAYED 4
#ELSE
#IF_EVENT_PLAYED 1
#IF_FORCE_RATIO E 6 2 L 5
#IF_CAMPAIGN_DAY G 5
#CHANGE_RELATIONS 4 6 1
#SHIFT_INITIATIVE 6 2 20
#SET_PAK_PRIORITY 2 1400 50
#SET_PAK_PRIORITY 2 1356 50
#SET_PAK_PRIORITY 2 173 80
#SET_PAK_PRIORITY 6 1400 50
#SET_PAK_PRIORITY 6 1356 50
#SET_PAK_PRIORITY 6 173 50
#PLAY_MOVIE 110
#DO_EVENT 4
#ENDIF
#ENDIF
#ENDIF
#ENDIF

//Tel Aviv being attacked by Arab forces
#IF_EVENT_PLAYED 5
#ELSE
#IF_CONTROLLED 6 O 183 186 182 457 190 191 452 3143 187 6628 189 316 451 184 181 180 453
#PLAY_MOVIE 100
#SET_PAK_PRIORITY 6 183 100
#SET_PAK_PRIORITY 2 183 100
#CHANGE_PRIORITIES 6 2
#CHANGE_PRIORITIES 2 1
#SET_TEMPO 255
#DO_EVENT 5
#ENDIF
#ENDIF

//Tel Aviv falls/regained
#IF_EVENT_PLAYED 6
#IF_CONTROLLED 2 A 183 3143 187 186 182
#SHIFT_INITIATIVE 6 2 50
#RESET_EVENT 6
#ENDIF
#ELSE
#IF_CONTROLLED 6 A 183 3143 187 186 182
#PLAY_MOVIE 101
#DO_EVENT 6
#SHIFT_INITIATIVE 2 6 50
#ENDIF
#ENDIF

// Cairo being attacked by Israeli forces
#IF_EVENT_PLAYED 7
#ELSE
#IF_CONTROLLED 2 O 1100 1018 1017 6656 2118 2180 6654 1019 1064 6655 5729 6657 1062
#PLAY_MOVIE 102
#SET_PAK_PRIORITY 6 1100 100
#SET_PAK_PRIORITY 2 1100 100
#CHANGE_PRIORITIES 6 1
#CHANGE_PRIORITIES 2 2
#SET_TEMPO 255
#DO_EVENT 7
#ENDIF
#ENDIF

// Cairo falls/regained
#IF_EVENT_PLAYED 8
#IF_CONTROLLED 6 A 1100 6656 2180 2255
#SHIFT_INITIATIVE 2 6 50
#RESET_EVENT 8
#ENDIF
#ELSE
#IF_CONTROLLED 2 A 1100 6656 2180 2255
#PLAY_MOVIE 103
#DO_EVENT 8
#SHIFT_INITIATIVE 6 2 50
#ENDIF
#ENDIF

// Damasqus being attacked by Israeli forces
#IF_EVENT_PLAYED 10
#ELSE
#IF_CONTROLLED 2 O 1584 1486 1487 1485 1829 1489 1474 1832 1821 5945 1490 1488 2152 1616 2125
#PLAY_MOVIE 108
#SET_PAK_PRIORITY 6 1487 100
#SET_PAK_PRIORITY 2 1487 100
#CHANGE_PRIORITIES 6 1
#CHANGE_PRIORITIES 2 2
#SET_TEMPO 255
#DO_EVENT 10
#ENDIF
#ENDIF

// Damasqus falls/regained
#IF_EVENT_PLAYED 11
#IF_CONTROLLED 6 A 1487 1485 1486 1488 1489 1829
#SHIFT_INITIATIVE 2 6 50
#RESET_EVENT 11
#ENDIF
#ELSE
#IF_CONTROLLED 2 A 1487 1485 1486 1488 1489 1829
#PLAY_MOVIE 109
#DO_EVENT 11
#SHIFT_INITIATIVE 6 2 50
#ENDIF
#ENDIF

//U.S. joins Israel
#IF_EVENT_PLAYED 12
#ELSE
#IF_FORCE_RATIO E 2 6 L 5
#IF_CAMPAIGN_DAY G 3
#CHANGE_RELATIONS 1 2 1
#SET_PAK_PRIORITY 2 760 40
#SHIFT_INITIATIVE 2 6 20
#PLAY_MOVIE 111
#DO_EVENT 12
#ENDIF
#ENDIF
#ENDIF

// Arabs own Tel Aviv, and the closest airbase
#IF_CONTROLLED 6 A 183 370
#PLAY_MOVIE 113
#DO_EVENT 14
#END_GAME 14
#ENDIF

//#IF_BORDOM_HOURS 420
//#PLAY_MOVIE 115
//#DO_EVENT 15
//#END_GAME 15
//#ENDIF

#IF_CAMPAIGN_DAY G 30
#PLAY_MOVIE 115
#DO_EVENT 16
#END_GAME 16
#ENDIF

//Israel owns Cairo or Damasqus, and their closest airbases
#IF_CONTROLLED 2 A 1100 707
#PLAY_MOVIE 116
#DO_EVENT 17
#END_GAME 17
#ELSE
#IF_CONTROLLED 2 A 1487 1738
#PLAY_MOVIE 116
#DO_EVENT 17
#END_GAME 17
#ENDIF
#ENDIF
#ENDSCRIPT

Hope this helps!..

[Bird-FF]

Oh.. BTW the movie cues are triggering "New Reports" located in the lcktxtrc.irc file.

[Bird-FF]

Oh.. one more thing. A functioning TRI script will improve campaign activity immensely. I highly recommend a DETAILED TRI script for any campaign, it will dictate whats important to the AI, and structure a battle plan for both sides.

Plus you can add some unexpected occurances. For example, in this TRI script, if israel is getting it's ass kicked, the US comes into the conflict with a a/c carrier, but only after day 3.

[Peled]

Definately vy DETAILED TRI File !
It seem that you got there a Nice Campaign...---Time to Edit that to "Arrab Aliance -2007"....Isn't? ...
....I Guess it can be Used for any Israeli Scenario/Campaign....Just need to changed the PAK's Numbers and Values and the Obj. ID's.....Is'nt?...

....I Would like to Test that one ,With my Becoming "1973 Campaign".....

Now----Tell me Bird.... :

//Jordan joins the Arab war effort / Set up PAK priorities
#IF_EVENT_PLAYED 4
#ELSE
#IF_EVENT_PLAYED 1
#IF_FORCE_RATIO E 6 2 L 5
#IF_CAMPAIGN_DAY G 5

...

Is the 5th Line Command means, that Jordan Joined 'till the 5th Day The War??... or, is that means that in the 5th Day Jordan Join the War ??...

Peled.

[Peled]

ok Bird----Here's Another Question: I Got already a TRI File for my 1982 Campaign....But----I'm interested in Improving that one i have ....
.....Is there any Possibility to use only few of those Events that you provide here?...i mean---Tehnically----Is there any possibility to use the Neccesery Events that regard to that Scenario and NOT All these Submitted here ?....
.....I'm asking this because i already tried to use these one below...And all what i Got is a CTD !...Ofcourse i changed the Obj. ID's and PAK's Numbers there according to the Campaign....

....Did i forgot something Else ?...maybe changeing the Total Events (22) to the number i have here will solve that ?...or changing the Event Number ?
--------------------
Here what I tried:

--------------------

#TOTAL_EVENTS 22
#SET_EVENT 2
#SET_TEMPO 255
#ENDINIT


// Set up PAK priorities
#IF_EVENT_PLAYED 9
#ELSE
#CHANGE_RELATIONS 7 0 1
#CHANGE_RELATIONS 3 0 1
#SET_PAK_PRIORITY 2 1487 50
#SET_PAK_PRIORITY 2 580 50
#SET_PAK_PRIORITY 2 313 90
#SET_PAK_PRIORITY 2 9 90
#SET_PAK_PRIORITY 2 650 80
#SET_PAK_PRIORITY 2 1100 60
#SET_PAK_PRIORITY 2 1237 60
#SET_PAK_PRIORITY 2 760 10
#SET_PAK_PRIORITY 2 1400 0
#SET_PAK_PRIORITY 2 1356 0
#SET_PAK_PRIORITY 6 313 100
#SET_PAK_PRIORITY 6 173 80
#SET_PAK_PRIORITY 6 183 80
#SET_PAK_PRIORITY 6 1487 50
#SET_PAK_PRIORITY 6 580 50
#SET_PAK_PRIORITY 6 9 100
#SET_PAK_PRIORITY 6 650 50
#SET_PAK_PRIORITY 6 1100 50
#SET_PAK_PRIORITY 6 1237 50
#SET_PAK_PRIORITY 6 760 30
#SET_PAK_PRIORITY 6 1400 0
#SET_PAK_PRIORITY 6 1356 0
#DO_EVENT 9
#ENDIF
#ENDIF

//Syria joins Lebanon to start war effort
#IF_EVENT_PLAYED 1
#ELSE
#CHANGE_RELATIONS 5 6 1
#SHIFT_INITIATIVE 6 2 20
#PLAY_MOVIE 112
#DO_EVENT 1
#ENDIF
#ENDIF


//Israeli's on Offensive
#IF_EVENT_PLAYED 2
#IF_ON_OFFENSIVE 2
#SHIFT_INITIATIVE 6 2 50
#PLAY_MOVIE 106
#DO_EVENT 3
#RESET_EVENT 2
#ENDIF
#ENDIF

//Israeli's on Defensive
#IF_EVENT_PLAYED 3
#IF_ON_OFFENSIVE 6
#SHIFT_INITIATIVE 2 6 50
#PLAY_MOVIE 107
#DO_EVENT 2
#RESET_EVENT 3
#ENDIF
#ENDIF


// Beirut being attacked by Israeli forces
#IF_EVENT_PLAYED 7
#ELSE
#IF_CONTROLLED 2 O 1100 1018 1017 6656 2118 2180 6654 1019 1064 6655 5729 6657 1062
#PLAY_MOVIE 102
#SET_PAK_PRIORITY 6 1100 100
#SET_PAK_PRIORITY 2 1100 100
#CHANGE_PRIORITIES 6 1
#CHANGE_PRIORITIES 2 2
#SET_TEMPO 255
#DO_EVENT 7
#ENDIF
#ENDIF


// Beirut falls/regained
#IF_EVENT_PLAYED 8
#IF_CONTROLLED 6 A 1100 6656 2180 2255
#SHIFT_INITIATIVE 2 6 50
#RESET_EVENT 8
#ENDIF
#ELSE
#IF_CONTROLLED 2 A 1100 6656 2180 2255
#PLAY_MOVIE 103
#DO_EVENT 8
#SHIFT_INITIATIVE 6 2 50
#ENDIF
#ENDIF

//#IF_BORDOM_HOURS 420
//#PLAY_MOVIE 115
//#DO_EVENT 15
//#END_GAME 15
//#ENDIF

#IF_CAMPAIGN_DAY G 30
#PLAY_MOVIE 115
#DO_EVENT 16
#END_GAME 16
#ENDIF

//Israel owns Beirut
#IF_CONTROLLED 2 A 1100 707
#PLAY_MOVIE 116
#DO_EVENT 17
#END_GAME 17
#ELSE
#IF_CONTROLLED 2 A 1487 1738
#PLAY_MOVIE 116
#DO_EVENT 17
#END_GAME 17
#ENDIF
#ENDIF
#ENDSCRIPT

BTW: Ofcourse that Team Relations were changed According my Scenario....

[Bird-FF]

quote://Israel owns Beirut
#IF_CONTROLLED 2 A 1100 707

oKAY i COPIED A LINE FROM WHAT YOUR DOING AS AN EXPAMPLE. Sorry for the caps lock. The bold are Tacedit Object Numbers, these must match objects in your campaign file. The number 2 is the team, and A is for All. There is a tutorial on this site on how to do it. I'm not sure if your campaigns have the same object numbers as my old ones, but this looks good to me.

[Peled]

quote:Originally posted by Bird-FF:
oKAY i COPIED A LINE FROM WHAT YOUR DOING AS AN EXPAMPLE. Sorry for the caps lock. The bold are Tacedit Object Numbers, these must match objects in your campaign file. The number 2 is the team, and A is for All. There is a tutorial on this site on how to do it. I'm not sure if your campaigns have the same object numbers as my old ones, but this looks good to me.

Well bird....i'm already Familiar with these manner of Creation...No needs for Tut ---NOW---- IIRC The OBJ. ID's in the Example are also Just for example...Not sure....'cause i deleted the original i've created already, after the CTD....Anyway....---This weekend after going on the 1973 Campaign i'll look at that again WITH the proper ID's...I Guess that we are useing differents Obj. ID's-----ok.....i'll report you what i achieved there, next week....Thanks!
The question was if it's tehniqaly possible to use just these commands(Triggers)for specific Scenario without need of all those 17 Events.....?

[Peled]

quote:Originally posted by Peled:
//Jordan joins the Arab war effort / Set up PAK priorities
#IF_EVENT_PLAYED 4
#ELSE
#IF_EVENT_PLAYED 1
#IF_FORCE_RATIO E 6 2 L 5
#IF_CAMPAIGN_DAY G 5

...

Is the 5th Line Command means, that Jordan Joined 'till the 5th Day The War??... or, is that means that in the 5th Day Jordan Join the War ??...

Peled.

bird-----Can you refer to that one too ?

[Bird-FF]

E means "Equals"
or
You can also use G with is "Greater"

So basically it means, that jordan won't enter untill sometime after day 5. If you would replace the G with E, jordan won't enter until exactly day 5. Usally you would use G in combination with other events.

Some like "if blue team is stronger, and it's sometime after day 5, makes team yellow join team red, only if red supplies are high enough, and only if red is past the line of death, etc.."

[Bird-FF]

quote:#IF_CAMPAIGN_DAY G 5

Sometime After day 5

quote:#IF_CAMPAIGN_DAY E 5

Exactly day 5

[Peled]

Understood.... Thank Ya !

[Peled]

ok....GOT It works :


--------------------------------

// FF3 Israeli Theater Update
// Campaign 2: Shlom Hagalil War-1982
// Campaign Designed by: Peled
//F4ITDG Projects

// initialize
#TOTAL_EVENTS 22
SET_EVENT 2#
#SET_TEMPO 255
#ENDINIT


//


//Syria joins Lebanon to start war effort
#IF_EVENT_PLAYED 1
#ELSE
#CHANGE_RELATIONS 5 6 1
#SHIFT_INITIATIVE 6 2 20
#DO_EVENT 1
#ENDIF
#ENDIF

//Israeli's on Offensive
#IF_EVENT_PLAYED 2
#IF_ON_OFFENSIVE 2
#SHIFT_INITIATIVE 6 2 50
#DO_EVENT 2
#RESET_EVENT 3
#ENDIF
#ENDIF

//Israeli's on Defensive
#IF_EVENT_PLAYED 3
#IF_ON_OFFENSIVE 6
#SHIFT_INITIATIVE 2 6 50
#DO_EVENT 3
#RESET_EVENT 2
#ENDIF
#ENDIF

// Sur West being attacked by Israeli forces
#IF_EVENT_PLAYED 4
#ELSE
#IF_CONTROLLED 2 O 502 503 504 523 524 525 526 532 533 535 536 617
SET_PAK_PRIORITY 2 502 90#
SET_PAK_PRIORITY 6 502 90#
#CHANGE_PRIORITIES 6 1
#CHANGE_PRIORITIES 5 2
#SET_TEMPO 255
#DO_EVENT 4
#ENDIF
#ENDIF

// Sur West falls/regained
#IF_EVENT_PLAYED 5
#IF_CONTROLLED 6 A 502 520 521 522 527 532 533 535 536 553
#SHIFT_INITIATIVE 2 6 50
#RESET_EVENT 5
#ENDIF
#ELSE
#IF_CONTROLLED 2 A 502 520 521 522 527 532 533 535 536 553
#DO_EVENT 5
#SHIFT_INITIATIVE 6 2 50
#ENDIF
#ENDIF

// Jezin being attacked by Israeli forces
#IF_EVENT_PLAYED 6
#ELSE
#IF_CONTROLLED 2 O 545 549 550
SET_PAK_PRIORITY 2 545 90#
SET_PAK_PRIORITY 6 545 90#
#CHANGE_PRIORITIES 6 1
#CHANGE_PRIORITIES 5 2
#SET_TEMPO 255
#DO_EVENT 6
#ENDIF
#ENDIF

// Jezin falls/regained
#IF_EVENT_PLAYED 7
#IF_CONTROLLED 6 A 545 549 550
#SHIFT_INITIATIVE 2 6 50
#RESET_EVENT 7
#ENDIF
#ELSE
#IF_CONTROLLED 2 A 545 549 550
#DO_EVENT 7
#SHIFT_INITIATIVE 6 2 50
#ENDIF
#ENDIF

// Ba'labakk West being attacked by Israeli forces
#IF_EVENT_PLAYED 8
#ELSE
#IF_CONTROLLED 2 O 526 525 523 524 533 532
SET_PAK_PRIORITY 2 526 90#
SET_PAK_PRIORITY 6 526 90#
#CHANGE_PRIORITIES 6 1
#CHANGE_PRIORITIES 5 2
#SET_TEMPO 255
#DO_EVENT 8
#ENDIF
#ENDIF

// Ba'labakk West falls/regained
#IF_EVENT_PLAYED 10
#IF_CONTROLLED 6 A 526 525 523 524
#SHIFT_INITIATIVE 2 6 50
#RESET_EVENT 10
#ENDIF
#ELSE
#IF_CONTROLLED 2 A 526 525 523 524
#DO_EVENT 10
#SHIFT_INITIATIVE 6 2 50
#ENDIF
#ENDIF

// Beirut being attacked by Israeli forces
#IF_EVENT_PLAYED 11
#ELSE
#IF_CONTROLLED 2 O 617 618 559 640
SET_PAK_PRIORITY 2 617 90#
SET_PAK_PRIORITY 6 617 90#
#CHANGE_PRIORITIES 6 1
#CHANGE_PRIORITIES 5 2
#SET_TEMPO 255
#DO_EVENT 11
#ENDIF
#ENDIF

// Beirut falls/regained
#IF_EVENT_PLAYED 12
#IF_CONTROLLED 6 A 617 618 640 527 637
#SHIFT_INITIATIVE 2 6 50
#RESET_EVENT 12
#ENDIF
#ELSE
#IF_CONTROLLED 2 A 617 618 640 527 637
#DO_EVENT 12
#SHIFT_INITIATIVE 6 2 50
#ENDIF
#ENDIF


//#IF_BORDOM_HOURS 420
//#DO_EVENT 13
//#END_GAME 13
//#ENDIF
#IF_CAMPAIGN_DAY G 30
#DO_EVENT 13
#END_GAME 13
#ENDIF

//Israel Win
# IF_CONTROLLED 2 A 617 520 521 522 523 524 525 526 532 535 536 502 503 504 543 545 549 550 553
#DO_EVENT 14
#END_GAME 14
#ENDIF
#ENDIF
#ENDSCRIPT

#ENDIF
#ENDIF
#ENDSCRIPT

----------------------------------

Thanks For Pointed me !

[Bird-FF]

quote:SET_PAK_PRIORITY 2 617 90#
SET_PAK_PRIORITY 6 617 90#

I see this alot, and its errorous. It should llok like this:

#SET_PAK_PRIORITY 2 617 90
#SET_PAK_PRIORITY 6 617 90

Not sure that it will cause problems, I think those lines will be ignored. This should be corrected.

[Peled]

quote:Originally posted by Bird-FF:
I see this alot, and its errorous. It should llok like this:

#SET_PAK_PRIORITY 2 617 90
#SET_PAK_PRIORITY 6 617 90

I Think i already GOT It like this.....You see that as it is NOW 'Cause my Copy & Paste from the tri. File.....My PC Doing that strangly....BUT---Just to Ensure what should be the Correct----Is it(#) Need to be Left or right of the txt ? ? ....As far as i know it should be right ...NO ?

[Bird-FF]

correct.. if the # is not before the txt, the line will be ignored

[Peled]

OK...That's really improving the Campaign !
...Now----Is there any Command i should use to: If Israeli Captured or attacking a City ,then ,their Ground Forces will Become Greater then the Enemy ?

...I'm asking this 'cause in the first hours of the Campaign,i found that Syria Got Greater Ground Forces then Israel....

So....Let's say if Zur have been Captured by Israeli ,then ,i want the Israeli Ground Supply will become Greater then the Syrian....

In my TRI the First Event is Regarding Zur....So ...How i modified this Event:

should i add an EVENT Like:

//Israeli Forces Got Supply
#IF_CONTROLLED 2 502
#DO_EVENT X
#IF_SUPPLY 2 6 2
#ELSE

[Peled]

Hmmm...little correction: In the Intel screen, there's :Supply and Ground Forces...
....So...what i meant is for Ground Forces !
I Just want the Israeli be Greater then the Enemy when they Capture a City....Is that possible to triggered ?

I Forgot The:# SHIFT_INITIATIVE Command....Ohhhhh...too much Commands to play with....i'm Confused Now...

BTW: Don't look at the # place...it's Just the strange way that my PC Is Copy/Paste...

[Bird-FF]

http://www.freebirdswing.org/libraries/ ... &ID=4#view

Download the RP5 Manual, and take a look at the designers notes, this should clear up some of your questions I think..

[Peled]

...Will Take a look , Thanks.

[Peled]

quote:Originally posted by Bird-FF:

//Jordan joins the Arab war effort / Set up PAK priorities
#IF_EVENT_PLAYED 4
#ELSE
#IF_EVENT_PLAYED 1
#IF_FORCE_RATIO E 6 2 L 5
#IF_CAMPAIGN_DAY G 5
#CHANGE_RELATIONS 4 6 1
#SHIFT_INITIATIVE 6 2 20
#SET_PAK_PRIORITY 2 1400 50
#SET_PAK_PRIORITY 2 1356 50
#SET_PAK_PRIORITY 2 173 80
#SET_PAK_PRIORITY 6 1400 50
#SET_PAK_PRIORITY 6 1356 50
#SET_PAK_PRIORITY 6 173 50
#PLAY_MOVIE 110
#DO_EVENT 4
#ENDIF
#ENDIF
#ENDIF
#ENDIF

Just Curious : Is there a meaning to 4X #ENDIF ?

#ENDIF
#ENDIF
#ENDIF
#ENDIF

What is that actually gives ? While , Usually it's Repeated Twice ?

Same Question For FEW Times that // is repeated eg. :

//
//
//


Thanks .


Peled.

[Bird-FF]

For every IF statement, there must be an ENDIF Statement. 4 IF's = 4 ENDIF's, and the possiblity of 4 ELSE's..

Example:

//Jordan joins the Arab war effort / Set up PAK priorities
#IF_EVENT_PLAYED 4
#ELSE
#IF_EVENT_PLAYED 1
#IF_FORCE_RATIO E 6 2 L 5
#IF_CAMPAIGN_DAY G 5
#CHANGE_RELATIONS 4 6 1
#SHIFT_INITIATIVE 6 2 20
#SET_PAK_PRIORITY 2 1400 50
#SET_PAK_PRIORITY 2 1356 50
#SET_PAK_PRIORITY 2 173 80
#SET_PAK_PRIORITY 6 1400 50
#SET_PAK_PRIORITY 6 1356 50
#SET_PAK_PRIORITY 6 173 50
#PLAY_MOVIE 110 // Jordan has joined Syria's war effort.
#DO_EVENT 4
#ENDIF
#ENDIF
#ELSE
#PLAY_MOVIE 117 //Something about Jordan thinking about joining up with Syria.
#ENDIF
#ELSE
#PLAY_MOVIE 116 //Something about conflict getting to close to borders. Jordan about to join Syria's war effort.
#ENDIF

[Peled]

K....Thanks.

So...IF I Understood it Correctly , I Need to Remove one Of the ENDIF Command in this Win Trigger ? :

// Israel Win
# IF_CONTROLLED 2 A 617 523 524 525 526 501 502 503 504 509 515 543 545 550
#DO_EVENT 14
#END_GAME 14
#ENDIF
#ENDIF <--(Is This Line Should Be Removed?)
#ENDSCRIPT

#ENDIF
#ENDIF
#ENDSCRIPT


That's the Last Event Triggered For the SHW Campaign...Although it seems that i Won 1 Campaign Already as with this Tri File...

BUT---I'm still Curious.....

[Bird-FF]

Seems to to me you got it.. remove that..


explaination #2:

//Jordan joins the Arab war effort / Set up PAK priorities
#IF_EVENT_PLAYED 4 //(1)
#ELSE //(1)
#IF_EVENT_PLAYED 1 //(2)
#IF_FORCE_RATIO E 6 2 L 5 //(3)
#IF_CAMPAIGN_DAY G 5 //(4)
#CHANGE_RELATIONS 4 6 1
#SHIFT_INITIATIVE 6 2 20
#SET_PAK_PRIORITY 2 1400 50
#SET_PAK_PRIORITY 2 1356 50
#SET_PAK_PRIORITY 2 173 80
#SET_PAK_PRIORITY 6 1400 50
#SET_PAK_PRIORITY 6 1356 50
#SET_PAK_PRIORITY 6 173 50
#PLAY_MOVIE 110 // Jordan has joined Syria's war effort.
#DO_EVENT 4
#ENDIF //(1)
#ENDIF //(2)
#ELSE //(3)
#PLAY_MOVIE 117 //Something about Jordan thinking about joining up with Syria.
#ENDIF //(3)
#ELSE //(4)
#PLAY_MOVIE 116 //Something about conflict getting to close to borders. Jordan about to join Syria's war effort.
#ENDIF //(4)

[Peled]

Hmmm...not quite sure what you are talking 'bout.....IF You are refering to the Win Condition in the Post above you...---well...it's for another Campaign...
Anyway.....I Got it....

[Bird-FF]

IT was just an expample of the IF ELSE END_IF

Look at the number //(#)

[Peled]

I Just Don't Want to Open a New Thread For That , and Since the Topic Says " Theatre Trigger Question " , I Thought to Post here my Next Question .

Here It Is :

Can Bridges Triggered In The tri File , and Take a Part In the Win Triggered Event ? I Mean as an Obj. To Capture For a Win ?
Or Just Cities Counts Here ?

My Example :

// Arabs own Hermon and Mitla Pass
#IF_CONTROLLED 6 A 391 1908 2145 6063
#DO_EVENT 14
#END_GAME 14
#ENDIF

While 6063 Is The Obj. ID For Mitla Bridge .

Another Thing I Noted , Is that 6063 Is Defined as a NoName Obj.

Maybe these 2 Questions will Let me Progress.....

Any Ideas ?

Don't stuck please on the NoName matter...I'll Remove it.... Just Tell me Please IF Bridges Can take a Part in that Event Too , or Just Cities ?

Next Question related to these lines :
*Example*

#IF_CONTROLLED 2 O 1138 1136 1137 1139 1140
#SET_PAK_PRIORITY 2 1138 100
#SET_PAK_PRIORITY 6 1138 100


Now......I Read once , that this order should NOT Be valuated with 100 ! Just 90 or less.....I Don't get any CTD With that 100 Value.....but....it seems that there are some Conflicts within the Developers Suggestions.....WHAT is your Thought ?

[Bird-FF]

okay.. The bridge should be fine, to change the name, go into tacedit edit the objective, and save the wch file..

Never heard of the 100 thingy.. Can't help you there..

[Peled]

ok , My personal thought is , there's no reason WHY Not useing the 100 thingy...Works fine here.


Anyway , thanks .

[Peled]

Here's another Trigger Question :

I'm Just Confused a Little

Look at That Trigger :

// Suez being attacked by Israeli forces
#IF_EVENT_PLAYED 5
#ELSE
#IF_CONTROLLED 2 O 1009 1008 1007 1010 1011
#SET_PAK_PRIORITY 2 1008 100
#SET_PAK_PRIORITY 6 1008 100
#CHANGE_PRIORITIES 6 1
#CHANGE_PRIORITIES 2 2
#SET_TEMPO 255
#DO_EVENT 5
#ENDIF
#ENDIF


Now ....

Before I Used it , I was Useing This Trigger :

// Suez being attacked by Israeli forces
#IF_EVENT_PLAYED 5
#ELSE
#IF_CONTROLLED 2 O 1009 1008 1007 1010 1011
#SET_PAK_PRIORITY 2 1008 100
#SET_PAK_PRIORITY 6 1008 100
#CHANGE_PRIORITIES 6 1
#CHANGE_PRIORITIES 5 2
#SET_TEMPO 255
#DO_EVENT 5
#ENDIF
#ENDIF


So....

In Case a City is Attacked :
#CHANGE_PRIORITIES 2 2
Eighter
#CHANGE_PRIORITIES 5 2

Works Fine to me....But ...Actually WHAT'S The effect of the 5 2 Or 2 2 ?


Any Point Here ?
It seems Nothing Critic had been Changed there....